Создание внешней печатной формы, подключаемой к документу 1с

Задача:Необходимо создать печатную форму “Спецификация” к документу Реализация товаров и услуг.

1.Создаем внешнюю обработку

2.Добавляем  реквизит СсылкаНаОбъект с типом  необходимого документа (в моем случае ДокументСсылка.РеализацияТоваровУслуг)

3.Добавляем в обработку форму для облегчения дальнейшей отладки

4.Размещаем на форме реквизит СсылкаНаОбъект

5.В модуле обработки создаем функцию печать(с пометкой экспорт) и назначаем ее на кнопку ‘Выполнить’ в форме обработке

код модуля:

Функция Печать() Экспорт
 Возврат(ПечатьСпецификации());
КонецФункции

Функция ПечатьСпецификации()
  Сообщить("Здесь будет Печатная форма"); 
КонецФункции

код формы:

Процедура КнопкаВыполнитьНажатие(Кнопка)
 Печать();
КонецПроцедуры

6. Уже можно подключать обработку к документу. Добавляем ее в дополнительные  печатные формы и определяем принадлежность к документу.

7.Теперь из документа “Реализация Товаров и Услуг” по команде печать можно выбрать и запустить эту обработку, результатом будет выполнение команд в  Функции ПечатьСпецификации()

8. Теперь можно приступить непосредственно к созданию макета печатной формы(текст, параметры, оформление, области). Подробнее почитать можно в статье Пример создания внешнего отчета в 1с

9.Для обращения к данным документа как раз и используется реквизит СсылкаНаОбъект, который будет равняться  ссылке на документ из которого вы хотите распечатать.

Функция ПечатьСпецификации()
 // выполняем запрос для получения данных о продавце и покупателе
 ЗапросШапкаПодвал = Новый Запрос;
 ЗапросШапкаПодвал.УстановитьПараметр("ТекущийДокумент", СсылкаНаОбъект);
 ЗапросШапкаПодвал.Текст =
 "ВЫБРАТЬ
 | РеализацияТоваровУслуг.Дата,
 | РеализацияТоваровУслуг.ДоговорКонтрагента,
 | РеализацияТоваровУслуг.Контрагент КАК Покупатель,
 | РеализацияТоваровУслуг.Организация КАК Поставщик,
 | РеализацияТоваровУслуг.СуммаДокумента,
 | РеализацияТоваровУслуг.СуммаВключаетНДС,
 | РеализацияТоваровУслуг.Сделка,
 | ВЫБОР
 |  КОГДА РеализацияТоваровУслуг.БанковскийСчетОрганизации.Ссылка ЕСТЬ NULL
 |   ТОГДА РеализацияТоваровУслуг.Организация.ОсновнойБанковскийСчет
 |  ИНАЧЕ РеализацияТоваровУслуг.БанковскийСчетОрганизации
 | КОНЕЦ КАК БанковскийСчетОрганизации,
 | РеализацияТоваровУслуг.ДоговорКонтрагента.Дата КАК ДатаДоговора,
 | РеализацияТоваровУслуг.Контрагент.ОсновноеКонтактноеЛицо как ДиректорП,
 | РеализацияТоваровУслуг.Контрагент.ОсновноеКонтактноеЛицо.Должность как ДолжностьП
 |ИЗ
 | Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
 |ГДЕ
 | РеализацияТоваровУслуг.Ссылка = &ТекущийДокумент";
 
 Шапка = ЗапросШапкаПодвал.Выполнить().Выбрать();
 Шапка.Следующий();
 
 ДанныеПокупателя=УправлениеКонтактнойИнформацией.СведенияОЮрФизЛице(Шапка.Покупатель, Шапка.Дата);
 ДанныеПоставщика=УправлениеКонтактнойИнформацией.СведенияОЮрФизЛице(Шапка.Поставщик, Шапка.Дата,, Шапка.БанковскийСчетОрганизации);
 ТабДокумент = Новый ТабличныйДокумент;
 //подключаем макет и области
 Макет       = ПолучитьМакет("Макет");
 
 ОбластьШапкаОтчета = Макет.ПолучитьОбласть("ШапкаОтчета");
 ОбластьСтрокиТаблицы = Макет.ПолучитьОбласть("СтрокиТаблицы");
 ОбластьПодвалОтчета = Макет.ПолучитьОбласть("ПодвалОтчета");
 
 // указываем  значения параметров в шапке и выводим область шапки
 ОбластьШапкаОтчета.параметры.ДатаДоговора="от "+формат(шапка.ДатаДоговора,"ДЛФ=DD");
 ОбластьШапкаОтчета.параметры.ДатаПоставки=" "+формат(Шапка.Дата,"ДЛФ=DD");
 ТабДокумент.Вывести(ОбластьШапкаОтчета);
 //выводими строки таблицы спецификации
 //нас интересуют только товары , без услуг
 товары = СсылкаНаОбъект.Товары;
 н = 0;
 //пробегаем по строкам табличной части товары документа Реализация товаров и услуг
 Для каждого т Из товары Цикл
  н=н+1;
  //на всякий случай включим обработку на исключение ошибки (некорректные данные, деление на 0 итп)
  попытка
   ОбластьСтрокиТаблицы.параметры.номер=н;
   ОбластьСтрокиТаблицы.параметры.продукция=т.Номенклатура;
   ОбластьСтрокиТаблицы.параметры.ЕдИзм=т.ЕдиницаИзмерения;
   ОбластьСтрокиТаблицы.параметры.КолВо=т.Количество;
   ОбластьСтрокиТаблицы.параметры.Цена=окр((т.СуммаНДС+т.Сумма)/т.Количество,2);
   ОбластьСтрокиТаблицы.параметры.Сумма=т.СуммаНДС+т.Сумма;
  Исключение
   Сообщить(ОписаниеОшибки())
  КонецПопытки;
  
  ТабДокумент.Вывести(ОбластьСтрокиТаблицы);
 КонецЦикла;
 // вывод подвала документа 
 ОбластьПодвалОтчета.параметры.ДатаПоставки=" "+формат(Шапка.Дата,"ДФ=dd.MM.yyyy");
 
 // данные поставщика
 ОбластьПодвалОтчета.Параметры.НазваниеП=""+ДанныеПоставщика.ПолноеНаименование;
 ОбластьПодвалОтчета.Параметры.АдресП=""+ДанныеПоставщика.ЮридическийАдрес;
 ОбластьПодвалОтчета.Параметры.ИННП="ИНН "+ДанныеПоставщика.ИНН+" КПП "+ ДанныеПоставщика.КПП;
 ОбластьПодвалОтчета.Параметры.РСП="р/с "+ДанныеПоставщика.НомерСчета;
 ОбластьПодвалОтчета.Параметры.БанкП=""+ДанныеПоставщика.Банк;
 ОбластьПодвалОтчета.Параметры.БИКП="БИК"+ДанныеПоставщика.Бик;
 Руководители = РегламентированнаяОтчетность.ОтветственныеЛицаОрганизаций(Шапка.Поставщик, шапка.Дата,);
 ОбластьПодвалОтчета.Параметры.ДолжностьП="Генеральный директор ";
 ОбластьПодвалОтчета.Параметры.ФИОП = ""+Руководители.Руководитель;
 
 
 //данные покупателя
 ОбластьПодвалОтчета.Параметры.Название=""+ДанныеПокупателя.ПолноеНаименование;
 ОбластьПодвалОтчета.Параметры.Адрес=""+ДанныеПокупателя.ЮридическийАдрес;
 ОбластьПодвалОтчета.Параметры.ИНН="ИНН "+ДанныеПокупателя.ИНН+" КПП "+ ДанныеПоставщика.КПП;
 ОбластьПодвалОтчета.Параметры.РС="р/с "+ДанныеПокупателя.НомерСчета;
 ОбластьПодвалОтчета.Параметры.Банк=""+ДанныеПокупателя.Банк;
 ОбластьПодвалОтчета.Параметры.БИК="БИК "+ДанныеПокупателя.Бик;
 ОбластьПодвалОтчета.Параметры.Должность=" "+Шапка.ДолжностьП;
 ОбластьПодвалОтчета.Параметры.ФИО=" "+Шапка.ДиректорП;
 
 
 ТабДокумент.Вывести(ОбластьПодвалОтчета);
 //
 УниверсальныеМеханизмы.НапечататьДокумент(ТабДокумент, , , "Спецификация");
 
 
КонецФункции

10. Не забудьте обновить печатную форму в справочнике “Дополнительные печатные формы и обработки”.

Поделиться ссылкой: